10 HOME
20 PRINT CHR$(4);"PR#3"
25 GOSUB 20000
27 HOME
30 DIM B(20,80)
32 DIM C(1600)

34 DIM W(1,80)

35 X1=10:Y1=42:X9=10:Y9=40:V8=10:V9=38:BB=0:LL=0:O1=0:C6=0:G1=0:MA=0

36 FOR I=1 TO 8
37 M(I)=I
38 NEXT I

39 INVERSE:VTAB 23:HTAB 1:PRINT" PLEASE INSERT A DATA DISK IN SLOT 6 DRIVE 2,THEN PRESS <SPC> TO BE CONTINUE. ":VTAB 23:HTAB 79:GET G$:VTAB 23:HTAB 79:PRINT G$:NORMAL:D2=1:GOSUB 15800

40 INVERSE:VTAB 23:HTAB 1:PRINT"                                                                               ":VTAB 23:HTAB 1:INPUT"INPUT A NUMBER BETWEEN 1 TO 99999 : ";RDS:NORMAL
41 IF RDS<1 OR RDS>99999 THEN 40

42 NORMAL:HOME

44 VTAB 10:HTAB 40:PRINT " "
45 VTAB 10:HTAB 40:PRINT "M"
50 INVERSE:VTAB 10:HTAB 42:PRINT "$":NORMAL
52 VTAB 20:HTAB 6:PRINT"Y":VTAB 20:HTAB 10:PRINT"I":VTAB 20:HTAB 15:PRINT"R - RUN":VTAB 20:HTAB 25:PRINT"S - SAVE MAZE":VTAB 20:HTAB 66:PRINT"DOLLAR :    0"
54 VTAB 21 :HTAB 5:PRINT"G H":VTAB 21:HTAB 9:PRINT"J K":VTAB 21:HTAB 25:PRINT"L - LOAD MAZE":VTAB 21:HTAB 42:PRINT"X - CATALOG":VTAB 21:HTAB 55:PRINT"O - HELP":VTAB 21:HTAB 66:PRINT"  STEP :    0"
56 VTAB 22 :HTAB 6:PRINT"B":VTAB 22:HTAB 10:PRINT"M":VTAB 22:HTAB 15:PRINT"Q - QUIT":VTAB 22:HTAB 25:PRINT"C - CLEAR SCN":VTAB 22:HTAB 42:PRINT"U - CLEAR ROUTE":VTAB 22:HTAB 66:PRINT"RESTEP :    0"

58 INVERSE:VTAB 23:HTAB 1:PRINT"                                                                               ":NORMAL

59 GOSUB 1200

60 NO=0:R1=0

61 INVERSE:VTAB 23:HTAB 50:PRINT"COMMON MODE     ":NORMAL

62 IF V8=10 AND V9=38 AND G1=0 THEN 64

63 IF G1>0 THEN INVERSE:VTAB 23:HTAB 50:PRINT"TARGET MODE     ":NORMAL:VTAB V8:HTAB V9:PRINT"T"


64 IF MA=1 THEN NORMAL:VTAB 23:HTAB 45:PRINT"SET"
65 IF MA=0 THEN NORMAL:VTAB 23:HTAB 45:PRINT"RND"

66 VTAB X9:HTAB Y9:PRINT"M":INVERSE:VTAB X1:HTAB Y1:PRINT"$":VTAB 23:HTAB 1:PRINT"COMMAND :                                   ":VTAB 23:HTAB 15:PRINT T$:VTAB 23:HTAB 11:GET A$:VTAB 23:HTAB 11:PRINT A$:NORMAL

72 IF A$="Q" THEN 9000

74 IF A$=CHR$(25) THEN X2=X1-1:Y2=Y1:GOSUB 1000:GOSUB 29000:X1=X2:Y1=Y2
75 IF A$=CHR$(7) THEN X2=X1:Y2=Y1-1:GOSUB 1000:GOSUB 29000:X1=X2:Y1=Y2
76 IF A$=CHR$(8) THEN X2=X1:Y2=Y1+1:GOSUB 1000:GOSUB 29000:X1=X2:Y1=Y2
77 IF A$=CHR$(2) THEN X2=X1+1:Y2=Y1:GOSUB 1000:GOSUB 29000:X1=X2:Y1=Y2

78 IF A$="I" THEN X2=X1-1:Y2=Y1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT"$":GOSUB 1100:B(X1,Y1)=1:GOSUB 1200:X1=X2:Y1=Y2
80 IF A$="J" THEN X2=X1:Y2=Y1-1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT"$":GOSUB 1100:B(X1,Y1)=1:GOSUB 1200:X1=X2:Y1=Y2

90 IF A$="K" THEN X2=X1:Y2=Y1+1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT"$":GOSUB 1100:B(X1,Y1)=1:GOSUB 1200:X1=X2:Y1=Y2
95 IF A$="M" THEN X2=X1+1:Y2=Y1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT"$":GOSUB 1100:B(X1,Y1)=1:GOSUB 1200:X1=X2:Y1=Y2
100 IF A$="Y" THEN X2=X1-1:Y2=Y1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT" ":GOSUB 1150:B(X1,Y1)=0:GOSUB 1200:X1=X2:Y1=Y2
110 IF A$="G" THEN X2=X1:Y2=Y1-1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT" ":GOSUB 1150:B(X1,Y1)=0:GOSUB 1200:X1=X2:Y1=Y2
120 IF A$="H" THEN X2=X1:Y2=Y1+1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT" ":GOSUB 1150:B(X1,Y1)=0:GOSUB 1200:X1=X2:Y1=Y2
130 IF A$="B" THEN X2=X1+1:Y2=Y1:GOSUB 1000:INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL:VTAB X1:HTAB Y1:PRINT" ":GOSUB 1150:B(X1,Y1)=0:GOSUB 1200:X1=X2:Y1=Y2
160 IF A$="R" THEN 6000
170 IF A$="S" THEN 15000
180 IF A$="L" THEN 15100
182 IF A$="C" THEN 15500
184 IF A$="X" THEN 15800
185 IF A$="O" THEN 18000
186 IF A$="E" AND C6>0 THEN 6300
188 IF A$="U" THEN VTAB 20:HTAB 39:PRINT"                           ":INVERSE:VTAB 23:HTAB 66:PRINT"             ":NORMAL:GOSUB 21000
191 IF A$=CHR$(6) THEN 33000

192 IF A$=CHR$(15) THEN 30000

193 IF A$=CHR$(26) THEN C6=0:NORMAL:VTAB 21:HTAB 15:PRINT"        ":GOTO 43000

194 IF A$=CHR$(14) THEN 52000

195 IF A$=CHR$(1) THEN MA=0:NORMAL:VTAB 23:HTAB 45:PRINT"RND"

197 IF A$=CHR$(20) THEN 34000

198 IF A$=CHR$(19) THEN GOSUB 42000
199 IF A$=CHR$(18) THEN 41000

200 GOTO 60

300 X4=X9:Y4=Y9:I1=1:S1=0:H2=0
301 VTAB 20:HTAB 39:PRINT"                           ":VTAB 21:HTAB 75:PRINT"   0":VTAB 22:HTAB 75:PRINT"   0":INVERSE:VTAB 23:HTAB 66:PRINT"             ":NORMAL

302 INVERSE:VTAB 23:HTAB 1:PRINT"              RUNNING                       ":NORMAL

307 GOSUB 21000
308 IF G1>0 THEN GOSUB 40000


310 IF B(X9,Y9)=1 THEN B(X9,Y9)=0:VTAB X9:HTAB Y9:PRINT"M":BB=BB-1:GOSUB 1200


312 IF B(V8,V9)=1 AND G1>0 THEN B(V8,V9)=0:VTAB V8:HTAB V9:PRINT"T":BB=BB-1:GOSUB 1200 

314 IF B(X9,Y9+1)=1 AND B(X9+1,Y9+1)=1 AND B(X9+1,Y9)=1 AND B(X9+1,Y9-1)=1 AND B(X9,Y9-1)=1 AND B(X9-1,Y9-1)=1 AND B(X9-1,Y9)=1 AND B(X9-1,Y9+1)=1 THEN INVERSE:VTAB 20:HTAB 44:PRINT"NO EXIT":NORMAL:GOTO 60



315 VTAB X4:HTAB Y4:PRINT"M"
320 X5=X4:Y5=Y4

325 FOR I8=1 TO 8
330 IF M(I8)=4 AND B(X4+1,Y4-1)=0 THEN XX=X4+1:YY=Y4-1:Q=5:F1=1:GOTO 530
340 IF M(I8)=3 AND B(X4+1,Y4)=0 THEN XX=X4+1:YY=Y4:Q=4:F1=2:GOTO 530
350 IF M(I8)=2 AND B(X4+1,Y4+1)=0 THEN XX=X4+1:YY=Y4+1:Q=6:F1=3:GOTO 530
360 IF M(I8)=1 AND B(X4,Y4+1)=0 THEN XX=X4:YY=Y4+1:Q=3:F1=4:GOTO 530
370 IF M(I8)=8 AND B(X4-1,Y4+1)=0 THEN XX=X4-1:YY=Y4+1:Q=7:F1=5:GOTO 530
380 IF M(I8)=7 AND B(X4-1,Y4)=0 THEN XX=X4-1:YY=Y4:Q=2:F1=6:GOTO 530
390 IF M(I8)=6 AND B(X4-1,Y4-1)=0 THEN XX=X4-1:YY=Y4-1:Q=8:F1=7:GOTO 530
395 IF M(I8)=5 AND B(X4,Y4-1)=0 THEN XX=X4:YY=Y4-1:Q=1:F1=8:GOTO 530
398 NEXT I8

400 I1=I1-1:IF I1<1 THEN I1=1
410 A7=C(I1):C(I1)=23:H2=H2+1:N1=22:N2=78:GOSUB 900
420 IF A7=1 THEN YY=Y4+1:XX=X4
430 IF A7=4 THEN XX=X4-1:YY=Y4
440 IF A7=3 THEN YY=Y4-1:XX=X4
450 IF A7=2 THEN XX=X4+1:YY=Y4
460 IF A7=5 THEN XX=X4-1:YY=Y4+1
470 IF A7=6 THEN XX=X4-1:YY=Y4-1
480 IF A7=7 THEN XX=X4+1:YY=Y4-1
490 IF A7=8 THEN XX=X4+1:YY=Y4+1
500 GOTO 550
530 IF B(XX,YY)=2 THEN XX=X4:YY=Y4:ON F1 GOTO 340,350,360,370,380,390,395,400
540 C(I1)=Q:I1=I1+1
550 VTAB X4:HTAB Y4:PRINT" ":B(XX,YY)=2 

552 IF G1>0 AND XX=V8 AND YY=V9 THEN VTAB X5:HTAB Y5:PRINT" ":GOSUB 27000:S1=0:H2=0:GOTO 650


560 IF XX>19 OR XX<1 OR YY>79 OR YY<1 THEN VTAB X5:HTAB Y5:PRINT" ":GOSUB 27000:S1=0:H2=0:GOTO 650
570 X4=XX:Y4=YY:VTAB X4:HTAB Y4:PRINT"M":VTAB X5:HTAB Y5:PRINT" "
575 IF XX=X9 AND YY=Y9 THEN R1=R1+1:GOSUB 28000
577 IF R1>8 THEN R1=0:NO=1:INVERSE:VTAB 20:HTAB 44:PRINT"NO EXIT":NORMAL:GOTO 650
580 S1=S1+1:N1=21:N2=78
590 IF S1>9 THEN N2=N2-1
600 IF S1>99 THEN N2=N2-1
610 IF S1>999 THEN N2=N2-1
620 VTAB N1:HTAB N2: PRINT S1
640 GOTO 315

650 INVERSE:VTAB 23:HTAB 1:PRINT"              WAITING                       ":NORMAL
660 FOR I=0 TO 20
670 FOR J=0 TO 80
680 IF B(I,J)<>1 THEN B(I,J)=0
690 NEXT J
700 NEXT I
705 INVERSE:VTAB 23:HTAB 15:PRINT"        ":NORMAL
710 IF NO=1 THEN NO=0:GOTO 60
720 INVERSE:VTAB 20:HTAB 39:PRINT"SHORTCUT":NORMAL
730 X7=X9:Y7=Y9:I2=1:CUT=0
740 IF C(I2)=5 THEN X8=X7+1:Y8=Y7-1
750 IF C(I2)=4 THEN X8=X7+1:Y8=Y7
760 IF C(I2)=6 THEN X8=X7+1:Y8=Y7+1
770 IF C(I2)=3 THEN X8=X7:Y8=Y7+1
780 IF C(I2)=7 THEN X8=X7-1:Y8=Y7+1
790 IF C(I2)=2 THEN X8=X7-1:Y8=Y7
792 IF C(I2)=8 THEN X8=X7-1:Y8=Y7-1 
794 IF C(I2)=1 THEN X8=X7:Y8=Y7-1

795 IF G1>0 AND X8=V8 AND Y8=V9 THEN INVERSE:VTAB X7:HTAB Y7:PRINT" ":NORMAL:CUT=CUT+1:VTAB 20:HTAB 48:PRINT CUT:GOTO 8000


796 IF X8>19 OR X8<1 OR Y8>79 OR Y8<1 THEN INVERSE:VTAB X7:HTAB Y7:PRINT" ":NORMAL:CUT=CUT+1:VTAB 20:HTAB 48:PRINT CUT:GOTO 8000
800 VTAB X8:HTAB Y8:PRINT"M":INVERSE:VTAB X7:HTAB Y7:PRINT" ":NORMAL:CUT=CUT+1:VTAB 20:HTAB 48:PRINT CUT:X7=X8:Y7=Y8
810 I2=I2+1
880 GOTO 740

900 IF H2>9 THEN N2=N2-1
910 IF H2>99 THEN N2=N2-1
920 IF H2>999 THEN N2=N2-1
930 VTAB N1:HTAB N2: PRINT H2
940 RETURN

1000 IF X2<1 THEN X2=19
1010 IF X2>19 THEN X2=1
1020 IF Y2<1 THEN Y2=79
1030 IF Y2>79 THEN Y2=1
1040 RETURN

1100 IF B(X1,Y1)=0 THEN BB=BB+1
1110 RETURN 

1150 IF B(X1,Y1)=1 THEN BB=BB-1
1160 RETURN

1200 IF BB<0 THEN BB=0
1210 IF BB<10 AND BB>-1 THEN NN1=78
1220 IF BB<100 AND BB>9 THEN NN1=77
1230 IF BB<1000 AND BB>99 THEN NN1=76
1240 IF BB<10000 AND BB>999 THEN NN1=75
1250 VTAB 20:HTAB 75:PRINT"    "
1260 VTAB 20:HTAB NN1:PRINT BB
1270 RETURN

6000 IF MA=1 THEN 300

6001 T$=""

6002 VTAB 21:HTAB 15:PRINT"E - ECHO"
6005 C6=C6+1

6030 INVERSE:VTAB 23:HTAB 1:PRINT"              WAITING                       ":NORMAL

6040 FOR I=1 TO RDS
6050 SF=INT(RND(999)*8+1):SG=INT(RND(999)*8+1)
6060 TG=M(SF):M(SF)=M(SG):M(SG)=TG
6070 NEXT I

6080 FOR I=1 TO 8
6090 S(I)=M(I)
6095 NEXT I

6100 GOSUB 46100


6298 GOTO 300


6300 IF MA=1 THEN 300

6301 T$=""

6302 FOR I=1 TO 8
6310 M(I)=S(I)
6320 NEXT I

6322 GOSUB 46100

6330 GOTO 300






8000 REM
8001 INVERSE:VTAB 20:HTAB 53:PRINT"OPTIMIZE":FLASH:VTAB 23:HTAB 15:PRINT"WAITING":NORMAL:SSC=0:EE=0
8002 C(0)=X9*100+Y9
8010 FOR I=1 TO 1600
8020 IF C(I)=1 THEN C(I)=C(I-1)-1
8021 IF C(I)=2 THEN C(I)=C(I-1)-100
8022 IF C(I)=3 THEN C(I)=C(I-1)+1
8023 IF C(I)=4 THEN C(I)=C(I-1)+100
8024 IF C(I)=5 THEN C(I)=C(I-1)+99
8025 IF C(I)=6 THEN C(I)=C(I-1)+101
8026 IF C(I)=7 THEN C(I)=C(I-1)-99
8027 IF C(I)=8 THEN C(I)=C(I-1)-101
8028 NEXT I
8029 FOR S=0 TO 1600
8030 IF C(S)=23 OR C(S)=0 THEN 8035
8032 EE=EE+1
8035 NEXT S
8038 FOR I=0 TO 0+EE
8040 FOR J=0+EE+1 TO I+1 STEP -1
8050 IF C(J)=C(I)-1 OR C(J)=C(I)-100 OR C(J)=C(I)+1 OR C(J)=C(I)+100 OR C(J)=C(I)+99 OR C(J)=C(I)+101 OR C(J)=C(I)-99 OR C(J)=C(I)-101 THEN GOSUB 8500
8060 NEXT J
8070 NEXT I

8100 INVERSE:VTAB 23:HTAB 15:PRINT"       ":NORMAL
8110 FOR I=1 TO 1+EE
8120 XX=INT(C(I)/100):YY=C(I)-100*XX
8121 REM
8122 REM

8124 IF G1>0 AND XX=V8 AND YY=V9 THEN SSC=SSC+1:VTAB 20:HTAB 62:PRINT SSC:GOTO 60


8125 IF XX<1 OR XX>19 OR YY<1 OR YY>79 THEN SSC=SSC+1:VTAB 20:HTAB 62:PRINT SSC:GOTO 60
8130 FLASH:VTAB XX:HTAB YY:PRINT"M":NORMAL
8132 SSC=SSC+1
8133 REM
8134 REM
8135 VTAB 20:HTAB 62:PRINT SSC
8140 NEXT I
8145 REM
8146 REM
8147 REM
8150 GOTO 60


8500 K=I:L=J
8505 FOR M=K+1 TO 4+EE

8507 IF L>1600 THEN 8530

8510 C(M)=C(L):L=L+1
8520 NEXT M
8530 RETURN
  


9000 HOME:PRINT CHR$(4);"CATALOG"+",D1,S6":END



15000 INVERSE:VTAB 23:HTAB 1:PRINT"                                                 ":VTAB 23:HTAB 1:INPUT"FILENAME : ";F$:NORMAL
15005 INVERSE:VTAB 23:HTAB 50:PRINT"SAVING":NORMAL
15007 IF F$=CHR$(43) THEN INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 60

15009 IF LEN(F$) > 24 THEN INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 15000

15010 ONERR GOTO 22200

15012 PRINT CHR$(4);"OPEN";F$
15020 PRINT CHR$(4);"WRITE";F$ 
15030 FOR I=1 TO 19
15040 FOR J=1 TO 79
15050 PRINT B(I,J)
15060 NEXT J
15070 NEXT I
15080 PRINT CHR$(4);"CLOSE";F$

15081 PRINT CHR$(4);"OPEN";F$+".INDEX"
15082 PRINT CHR$(4);"WRITE";F$+".INDEX"
15083 PRINT X1:PRINT Y1:PRINT X9:PRINT Y9:PRINT V8:PRINT V9:PRINT G1:PRINT M(1):PRINT M(2):PRINT M(3):PRINT M(4):PRINT M(5):PRINT M(6):PRINT M(7):PRINT M(8):PRINT T$:PRINT MA
15084 PRINT CHR$(4);"CLOSE";F$+".INDEX"

15086 PRINT CHR$(4);"OPEN";F$+".BITMAP"
15088 PRINT CHR$(4);"WRITE";F$+".BITMAP" 
15090 FOR I=1 TO 19
15092 FOR J=1 TO 79
15093 PRINT B(I,J);
15094 NEXT J
15095 PRINT
15096 NEXT I
15097 PRINT CHR$(4);"CLOSE";F$+".BITMAP"

15098 INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL
15099 GOTO 60

15100 INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":VTAB 23:HTAB 1:INPUT"FILENAME : ";F$:NORMAL
15105 INVERSE:VTAB 23:HTAB 50:PRINT"LOADING":NORMAL
15106 IF F$=CHR$(43) THEN INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 60

15108 ONERR GOTO 22200

15110 PRINT CHR$(4);"OPEN";F$
15120 PRINT CHR$(4);"READ";F$ 
15130 FOR I=1 TO 19
15140 FOR J=1 TO 79
15150 INPUT B(I,J)
15160 NEXT J
15170 NEXT I
15180 PRINT CHR$(4);"CLOSE";F$
15181 PRINT CHR$(4);"OPEN";F$+".INDEX"
15182 PRINT CHR$(4);"READ";F$+".INDEX"
15183 INPUT X1:INPUT Y1:INPUT X9:INPUT Y9:INPUT V8:INPUT V9:INPUT G1:INPUT M(1):INPUT M(2):INPUT M(3):INPUT M(4):INPUT M(5):INPUT M(6):INPUT M(7):INPUT M(8):INPUT T$:INPUT MA
15184 PRINT CHR$(4);"CLOSE";F$+".INDEX"
15185 INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL
15187 GOSUB 15200

15188 IF G1>0 THEN INVERSE:VTAB 23:HTAB 50:PRINT"TARGET MODE     ":NORMAL
15190 IF G1=0 THEN RN=1:GOSUB 41000

15196 NORMAL:VTAB 20:HTAB 39:PRINT"                           "

15197 IF MA=1 THEN C6=0:NORMAL:VTAB 21:HTAB 15:PRINT"        "



15198 LL=1:GOSUB 1200:GOTO 60

15200 BB=0:VTAB 20:HTAB 75:PRINT"    ":VTAB 21:HTAB 75:PRINT"   0":VTAB 22:HTAB 75:PRINT"   0" 
15202 FOR I=1 TO 19
15210 FOR J=1 TO 79
15220 IF B(I,J)=1 THEN VTAB I:HTAB J:PRINT"$":BB=BB+1:GOSUB 1200
15222 IF B(I,J)<>1 THEN VTAB I:HTAB J:PRINT" "
15230 NEXT J
15240 NEXT I
15250 RETURN


15500 NORMAL:VTAB 20:HTAB 39:PRINT"                           ":INVERSE:VTAB 23:HTAB 66:PRINT"             ":NORMAL

15502 FOR I=1 TO 19
15510 FOR J=1 TO 79
15520 VTAB I:HTAB J:PRINT" "
15530 NEXT J
15540 NEXT I

15542 FOR I=0 TO 20
15543 FOR J=0 TO 80
15544 B(I,J)=0
15545 NEXT J
15546 NEXT I

15547 FOR I=0 TO 1600:C(I)=0:NEXT I

15548 BB=0
15549 VTAB 20:HTAB 75:PRINT"   0":VTAB 21:HTAB 75:PRINT"   0":VTAB 22:HTAB 75:PRINT"   0"
15550 GOTO 60

15800 HOME
15802 PRINT CHR$(4);"CATALOG"+",D2,S6"
15810 PRINT:PRINT"<PRESS ANY KEY TO BE CONTINUE>":NORMAL:GET CT$
15820 HOME:BB=0
15830 FOR I=1 TO 19
15840 FOR J=1 TO 79
15850 IF B(I,J)=1 THEN VTAB I:HTAB J:PRINT"$":BB=BB+1
15860 NEXT J
15870 NEXT I

15880 IF D2=1 THEN D2=0:RETURN

15990 GOTO 52


18000 HOME
18006 GOSUB 20040
18820 HOME:BB=0
18830 FOR I=1 TO 19
18840 FOR J=1 TO 79
18850 IF B(I,J)=1 THEN VTAB I:HTAB J:PRINT"$":BB=BB+1
18860 NEXT J
18870 NEXT I
18990 GOTO 52


20000 PRINT:PRINT:PRINT
20010 PRINT"                               MOUSE & MAZE"
20020 PRINT"                          DESIGNED BY TIMOTHY WEN"
20030 PRINT"                            09/2008 PD SOFTWARE"

20032 PRINT:PRINT:PRINT:PRINT"                       <PRESS ANY KEY TO BE CONTINUE>":NORMAL:GET CT$


20040 HOME
20050 PRINT"COMMAND :"
20060 PRINT
20070 PRINT"           I,J,K,M      ADD ELEMENT OF WALL TO BUILD MAZE."

20090 PRINT"           Y,G,H,B      DELETE ELEMENT OF WALL TO BUILD MAZE."

20092 PRINT
20094 PRINT"           ^Y,^G,^H,^B  JUST MOVE CURSOR,NO ADDING OR DELETING ELEMENT OF WALL."
20096 PRINT"                        (^ MEANS <CTRL> KEY)"
20110 PRINT

20120 PRINT"           R            RUN THE MOUSE.(RND/SET MODE)"

20140 PRINT"           E            RUN WITH THE SAME RULE (THE SAME AS LAST ONE)."
 


20160 PRINT"           Q            QUIT THE PROGRAM."

20180 PRINT"           S            SAVE MAZE PATTERN."

20200 PRINT"           L            LOAD MAZE PATTERN."

20220 PRINT"           C            CLEAR DESIGNING AREA."

20240 PRINT"           X            SHOW THE SAVED MAZE FILES."

20242 PRINT"           O            SHOW THE COMMAND HELP PAGE."

20244 PRINT"           U            CLEAR SHORTCUT AND OPTIMIZE ROUTE."

20250 PRINT:PRINT:PRINT:PRINT:PRINT"                       <PRESS ANY KEY TO BE CONTINUE>":NORMAL:GET CT$


20260 HOME
20262 PRINT
20270 PRINT"          ^F            IF YOU CAN'T LOAD THE MAZE OF OLD VERSION,"
20272 PRINT"                        TRY THIS FUNCTION."

20290 PRINT"          ^O            CHANGE ORIGINAL POSITION OF THE MOUSE."

20310 PRINT"          ^T            CHANGE TARGET POSITION OF THE MOUSE."

20330 PRINT"          ^R            RETURN TO COMMON MODE."
20332 PRINT"                        (TARGETS ARE THE EDGES OF DESIGNING AREA.)"

20350 PRINT"          ^S            CHANGE RANDOM SEED."

20370 PRINT"          ^Z            SET RUNNING RULES OF MOUSE BY YOURSELF."

20390 PRINT"          ^A            RETURN TO RANDOM MODE."

20410 PRINT"          ^N            USE ART TOOLS TO CHANGE PATTERN OF MAZE."

20420 PRINT:PRINT:PRINT:PRINT:PRINT"                       <PRESS ANY KEY TO BE CONTINUE>":NORMAL:GET CT$


20990 RETURN


21000 FOR I=1 TO 19
21010 FOR J=1 TO 79
21020 IF B(I,J)<>1 THEN VTAB I:HTAB J:PRINT" "
21030 NEXT J
21040 NEXT I
21050 RETURN



22200 Y=PEEK(222)

22210 IF Y=4 THEN INVERSE:VTAB 23:HTAB 50:PRINT"WRITE PROTECTED":NORMAL:GOSUB 22500:GOTO 60
22212 IF Y=7 THEN INVERSE:VTAB 23:HTAB 50:PRINT"VOLUME MISMATCH":NORMAL:GOSUB 22500:GOTO 60
22214 IF Y=8 THEN INVERSE:VTAB 23:HTAB 50:PRINT"I/O ERROR":NORMAL:GOSUB 22500:GOTO 60
22216 IF Y=9 THEN INVERSE:VTAB 23:HTAB 50:PRINT"DISK FULL":NORMAL:GOSUB 22500:GOTO 60
22218 IF Y=10 THEN INVERSE:VTAB 23:HTAB 50:PRINT"FILE LOCKED":NORMAL:GOSUB 22500:GOTO 60
22219 IF Y=11 THEN INVERSE:VTAB 23:HTAB 50:PRINT"SYNTAX ERROR":NORMAL:GOSUB 22500:GOTO 60
22220 IF Y=13 THEN INVERSE:VTAB 23:HTAB 50:PRINT"FILE TYPE MISMATCH":NORMAL:GOSUB 22500:GOTO 60

22298 INVERSE:VTAB 23:HTAB 50:PRINT"FILE NOT FOUND":NORMAL:GOSUB 22500:GOTO 60

22500 FOR I=1 TO 50000
22510 NEXT I

22520 RETURN



27000 S1=S1+1:N1=21:N2=78
27010 IF S1>9 THEN N2=N2-1
27020 IF S1>99 THEN N2=N2-1
27030 IF S1>999 THEN N2=N2-1
27040 VTAB N1:HTAB N2: PRINT S1
27050 RETURN


28000 IF R1>8 THEN RETURN
28010 INVERSE:VTAB 23:HTAB 66:PRINT"ROOT PASS : ";R1:NORMAL
28020 RETURN

29000 IF X1=10 AND Y1=40 THEN 29040
29010 IF B(X1,Y1)=1 THEN NORMAL:VTAB X1:HTAB Y1:PRINT"$"
29020 IF B(X1,Y1)=0 THEN NORMAL:VTAB X1:HTAB Y1:PRINT" "
29030 IF X2=10 AND Y2=40 THEN 29050
29040 INVERSE:VTAB X2:HTAB Y2:PRINT"$":NORMAL
 

29050 RETURN


30000 O1=O1+1
30004 X8=10:Y8=40
30006 IF O1>1 THEN X8=X9:Y8=Y9
30007 IF LL=1 THEN X8=X9:Y8=Y9
30008 INVERSE:VTAB 23:HTAB 1:PRINT"COMMAND :                                        CHANGE ORIGINAL POSITION      ":NORMAL

30010 INVERSE:VTAB 23:HTAB 11:GET A$:VTAB 23:HTAB 11:PRINT A$:NORMAL


30050 IF A$=CHR$(25) THEN X9=X8-1:Y9=Y8:GOSUB 32000:GOSUB 31000:X8=X9:Y8=Y9
30060 IF A$=CHR$(7) THEN X9=X8:Y9=Y8-1:GOSUB 32000:GOSUB 31000:X8=X9:Y8=Y9
30070 IF A$=CHR$(8) THEN X9=X8:Y9=Y8+1:GOSUB 32000:GOSUB 31000:X8=X9:Y8=Y9
30080 IF A$=CHR$(2) THEN X9=X8+1:Y9=Y8:GOSUB 32000:GOSUB 31000:X8=X9:Y8=Y9

30082 IF A$=CHR$(15) THEN 36000

30090 GOTO  30010




31000 IF B(X8,Y8)=1 THEN NORMAL:VTAB X8:HTAB Y8:PRINT"$"
31010 IF B(X8,Y8)=0 THEN NORMAL:VTAB X8:HTAB Y8:PRINT" "
31020 NORMAL:VTAB X9:HTAB Y9:PRINT"M"

31050 RETURN

32000 IF X9<1 THEN X9=19
32010 IF X9>19 THEN X9=1
32020 IF Y9<1 THEN Y9=79
32030 IF Y9>79 THEN Y9=1

32040 RETURN

33000 INVERSE:VTAB 23:HTAB 1:PRINT"                                                                              ":VTAB 23:HTAB 50:PRINT"MAZE FIXING":VTAB 23:HTAB 1:INPUT"FILENAME : ";F$:NORMAL


33002 IF F$=CHR$(43) THEN INVERSE:VTAB 23:HTAB 12:PRINT"                                                                    ":NORMAL:GOTO 60

33010 A9=10:B9=40:C8=10:D9=38:E1=0:FF=1

33012 N(1)=1:N(2)=2:N(3)=3:N(4)=4:N(5)=5:N(6)=6:N(7)=7:N(8)=8

33014 H$="R  DR  D  DL  L  UL  U  UR "


33081 PRINT CHR$(4);"OPEN";F$+".INDEX"
33082 PRINT CHR$(4);"READ";F$+".INDEX"
33083 INPUT T1:INPUT T2
33084 PRINT CHR$(4);"CLOSE";F$+".INDEX"


33181 PRINT CHR$(4);"OPEN";F$+".INDEX"
33182 PRINT CHR$(4);"WRITE";F$+".INDEX"
33183 PRINT T1:PRINT T2:PRINT A9:PRINT B9:PRINT C8:PRINT D9:PRINT E1:PRINT N(1):PRINT N(2):PRINT N(3):PRINT N(4):PRINT N(5):PRINT N(6):PRINT N(7):PRINT N(8):PRINT H$:PRINT FF
33184 PRINT CHR$(4);"CLOSE";F$+".INDEX"

33186 INVERSE:VTAB 23:HTAB 50:PRINT"           ":VTAB 23:HTAB 12:PRINT"                              ":NORMAL

33190 GOTO 60


34000 G1=G1+1
34002 G8=10:G9=38

34003 IF G1>1 OR LL=1 THEN G8=V8:G9=V9:NORMAL:VTAB G8:HTAB G9:PRINT"T":GOTO 34007


34004 NORMAL:VTAB G8:HTAB G9:PRINT"T"

34007 INVERSE:VTAB 23:HTAB 1:PRINT"COMMAND :                                        CHANGE TARGET POSITION        ":NORMAL


34010 INVERSE:VTAB 23:HTAB 11:GET A$:VTAB 23:HTAB 11:PRINT A$:NORMAL

34050 IF A$=CHR$(25) THEN V8=G8-1:V9=G9:GOSUB 37000:GOSUB 35000:G8=V8:G9=V9
34060 IF A$=CHR$(7) THEN V8=G8:V9=G9-1:GOSUB 37000:GOSUB 35000:G8=V8:G9=V9
34070 IF A$=CHR$(8) THEN V8=G8:V9=G9+1:GOSUB 37000:GOSUB 35000:G8=V8:G9=V9
34080 IF A$=CHR$(2) THEN V8=G8+1:V9=G9:GOSUB 37000:GOSUB 35000:G8=V8:G9=V9

34082 IF A$=CHR$(20) THEN 38000


34090 GOTO  34010


35000 IF B(G8,G9)=1 THEN NORMAL:VTAB G8:HTAB G9:PRINT"$"
35010 IF B(G8,G9)=0 THEN NORMAL:VTAB G8:HTAB G9:PRINT" "
35020 NORMAL:VTAB V8:HTAB V9:PRINT"T"

35050 RETURN


36000 IF B(X9,Y9)=1 THEN INVERSE:VTAB 23:HTAB 50:PRINT"STAND ON THE DOLLAR SIGN":GOTO 30010
36001 IF V8=10 AND V9=38 THEN 36010
36002 IF X9=V8 AND Y9=V9 THEN INVERSE:VTAB 23:HTAB 50:PRINT"M STAND ON T            ":GOTO 30010
36010 INVERSE:VTAB 23:HTAB 50:PRINT"                        ":NORMAL:GOTO 60

37000 IF V8<1 THEN V8=19
37010 IF V8>19 THEN V8=1
37020 IF V9<1 THEN V9=79
37030 IF V9>79 THEN V9=1

37040 RETURN


38000 IF B(V8,V9)=1 THEN INVERSE:VTAB 23:HTAB 50:PRINT"STAND ON THE DOLLAR SIGN":GOTO 34010
38002 IF X9=V8 AND Y9=V9 THEN INVERSE:VTAB 23:HTAB 50:PRINT"T STAND ON M            ":GOTO 34010
38010 INVERSE:VTAB 23:HTAB 50:PRINT"                        ":NORMAL:GOTO 60


40000 NORMAL:VTAB V8:HTAB V9:PRINT"T"

40002 FOR I=0 TO 80

40010 B(0,I)=1:B(20,I)=1
40020 NEXT I

40030 FOR J=0 TO 20
40040 B(J,0)=1:B(J,80)=1
40050 NEXT J


40090 RETURN

41000 IF B(V8,V9)=1 THEN B(V8,V9)=0:BB=BB-1:GOSUB 1200 

41002 NORMAL:VTAB V8:HTAB V9:PRINT" ":G1=0:V8=10:V9=38

41006 INVERSE:VTAB 23:HTAB 50:PRINT"COMMON MODE     ":NORMAL

41008 FOR I=0 TO 80

41010 B(0,I)=0:B(20,I)=0
41020 NEXT I

41030 FOR J=0 TO 20
41040 B(J,0)=0:B(J,80)=0
41050 NEXT J
41060 IF RN=1 THEN RN=0:RETURN

41090 GOTO 64


42000 INVERSE:VTAB 23:HTAB 1:PRINT"                                                                               ":VTAB 23:HTAB 1:INPUT"INPUT A NUMBER BETWEEN 1 TO 99999 : ";RDS:NORMAL
42001 IF RDS<1 OR RDS>99999 THEN 42000
42010 RETURN


43000 IN=1:PO=0:CH=1:MA=1:T$=""
43002 CU$(8)="UR ":CU$(1)="R ":CU$(2)="DR ":CU$(3)="D ":CU$(4)="DL ":CU$(5)="L ":CU$(6)="UL ":CU$(7)="U "


43004 INVERSE:VTAB 23:HTAB 1:PRINT"RULES :                                          ":NORMAL

43006 VTAB 23:HTAB 15:PRINT CU$(IN)

43008 INVERSE:VTAB 23:HTAB 9:GET A$:VTAB 23:HTAB 9:PRINT A$:NORMAL



43010 IF A$="J" THEN IN=IN-1:GOTO 43100
43020 IF A$="K" THEN IN=IN+1:GOTO 43100
43022 IF A$="M" AND PO<7 THEN T$=T$+CU$(IN)+" ":PO=PO+1:M(CH)=IN:CH=CH+1:IN=1:GOTO 43150
43023 IF A$="M" AND PO=7 THEN :T$=T$+CU$(IN)+" ":GOTO 44000

43030 IF A$=CHR$(43) THEN 46000

43050 GOTO 43008

43100 INVERSE:VTAB 23:HTAB 50:PRINT"             ":NORMAL

43102 IF IN>8 THEN IN=1
43110 IF IN<1 THEN IN=8


43150 VTAB 23:HTAB 15+PO*4:PRINT CU$(IN)

43160 GOTO 43008


44000 REM 

44002 M(CH)=IN
44010 REM 

44130 FOR I=1 TO CH-1
44131 FOR J=2 TO CH
44132 IF I=J THEN 44134
44133 IF M(I)=M(J) THEN 45000
44134 NEXT J
44136 NEXT I
 

44140 REM 

44142 REM 

44146 REM 


44150 REM 

44160 NORMAL:VTAB 23:HTAB 45:PRINT"SET":GOTO 60


45000 INVERSE:VTAB 23:HTAB 50:PRINT"RULE REPEATED":NORMAL
45010 GOTO 43000

46000 T$="R  DR  D  DL  L  UL  U  UR "

46002 FOR I=1 TO 8
46010 M(I)=I
46020 NEXT I


46030 GOTO 44150



46100 FOR I=1 TO 8
46102 IF M(I)=1 THEN P$(I)="R "
46104 NEXT I
46110 FOR I=1 TO 8
46112 IF M(I)=2 THEN P$(I)="DR "
46114 NEXT I
46120 FOR I=1 TO 8
46122 IF M(I)=3 THEN P$(I)="D "
46124 NEXT I
46130 FOR I=1 TO 8
46132 IF M(I)=4 THEN P$(I)="DL "
46134 NEXT I
46140 FOR I=1 TO 8
46142 IF M(I)=5 THEN P$(I)="L "
46144 NEXT I
46150 FOR I=1 TO 8
46152 IF M(I)=6 THEN P$(I)="UL "
46154 NEXT I
46160 FOR I=1 TO 8
46162 IF M(I)=7 THEN P$(I)="U "
46164 NEXT I
46170 FOR I=1 TO 8
46172 IF M(I)=8 THEN P$(I)="UR "
46174 NEXT I

46200 FOR I=1 TO 8
46202 T$=T$+P$(I)+" "
46206 NEXT I


46300 RETURN

52000 FOR ZC=0 TO 80
52002 W(1,ZC)=0
52004 NEXT ZC

52100 INVERSE:VTAB 23:HTAB 1:PRINT"COMMAND :                                        MAZE ART                     "
52102 VTAB 23:HTAB 11:GET A$:VTAB 23:HTAB 11:PRINT A$:NORMAL

52110 IF A$=CHR$(43) THEN NORMAL:VTAB X9:HTAB Y9:PRINT" ":VTAB V8:HTAB V9:PRINT" ":GOTO 60
52120 IF A$="F" THEN RT=0:GOTO 52140
52122 IF A$="R" THEN RT=1:GOTO 52300
52130 GOTO 52100

52140 REM

52150 INVERSE:VTAB 23:HTAB 1:PRINT"COMMAND :                                        FLIP                         "
52152 VTAB 23:HTAB 11:GET A$:VTAB 23:HTAB 11:PRINT A$:NORMAL
52160 IF A$=CHR$(43) THEN 53000
52170 IF A$="V" THEN CA=19:C1=10:C2=80:GOTO 52200
52180 IF A$="H" THEN CA=79:C1=40:C2=19:HR=1:GOTO 52200
52190 GOTO 52150

52200 FOR I=1 TO C1
52220 FOR J=1 TO C2
52225 IF HR=1 THEN W(1,J)=B(J,I):B(J,I)=B(J,CA):B(J,CA)=W(1,J):GOTO 52240
52230 W(1,J)=B(I,J):B(I,J)=B(CA,J):B(CA,J)=W(1,J)
52240 NEXT J
52245 CA=CA-1
52250 NEXT I

52260 FOR I=1 TO 19
52262 FOR J=1 TO 79
52263 IF I=S1 AND J=S2 THEN 52268
52264 IF SO=1 AND I=S1 AND J=S2 THEN 52268
52265 IF B(I,J)=1 THEN VTAB I:HTAB J:PRINT"$":GOTO 52268
52266 VTAB I:HTAB J:PRINT" "
52268 NEXT J
52269 NEXT I
52270 IF RT=1 THEN RETURN
52280 HR=0

52290 NORMAL:VTAB X9:HTAB Y9:PRINT"M":VTAB V8:HTAB V9:PRINT"T"

52292 GOTO 52140


52300 REM

52310 INVERSE:VTAB 23:HTAB 1:PRINT"COMMAND :                                        ROTATE                       "
52312 VTAB 23:HTAB 11:GET A$:VTAB 23:HTAB 11:PRINT A$:NORMAL
52320 IF A$="K" THEN DC=1:H1=H1+1:GOSUB 52500
52330 IF A$="J" THEN DC=2:H1=H1-1:GOSUB 52500
52340 IF A$="I" THEN DC=3:V1=V1+1:GOSUB 52500
52350 IF A$="M" THEN DC=4:V1=V1-1:GOSUB 52500
52390 IF A$=CHR$(43) THEN 53100

52398 GOTO 52310

52500 IF DC=3 THEN FOR J=1 TO 80:W(1,J)=B(1,J):NEXT J
52501 IF DC=4 THEN FOR J=1 TO 80:W(1,J)=B(19,J):NEXT J
52502 IF DC=1 THEN FOR J=1 TO 20:W(1,J)=B(J,79):NEXT J
52503 IF DC=2 THEN FOR J=1 TO 20:W(1,J)=B(J,1):NEXT J

52505 IF DC=3 THEN FOR I=1 TO 19:FOR J=1 TO 80:B(I,J)=B(I+1,J):NEXT J:NEXT I
52506 IF DC=4 THEN FOR I=19 TO 2 STEP -1:FOR J=1 TO 80:B(I,J)=B(I-1,J):NEXT J:NEXT I
52508 IF DC=1 THEN FOR I=1 TO 20:FOR J=80 TO 3 STEP -1:B(I,J-1)=B(I,J-2):NEXT J:NEXT I
52509 IF DC=2 THEN FOR I=1 TO 20:FOR J=1 TO 78:B(I,J)=B(I,J+1):NEXT J:NEXT I

52550 IF DC=3 THEN FOR J=1 TO 80:B(19,J)=W(1,J):NEXT J
52552 IF DC=4 THEN FOR J=1 TO 80:B(1,J)=W(1,J):NEXT J
52554 IF DC=1 THEN FOR J=1 TO 20:B(J,1)=W(1,J):NEXT J
52556 IF DC=2 THEN FOR J=1 TO 20:B(J,79)=W(1,J):NEXT J

52560 GOSUB 52260

52570 NORMAL:VTAB X9:HTAB Y9:PRINT"M":VTAB V8:HTAB V9:PRINT"T"

52590 RETURN


53000 IF B(V8,V9)=1 OR B(X9,Y9)=1 THEN INVERSE:VTAB 23:HTAB 40:PRINT"DOLLAR SIGN STAND ON M OR T":NORMAL:GOTO 52152
53010 GOTO 52100

53100 IF B(V8,V9)=1 OR B(X9,Y9)=1 THEN INVERSE:VTAB 23:HTAB 40:PRINT"DOLLAR SIGN STAND ON M OR T":NORMAL:GOTO 52312
53110 GOTO 52100


